1.3.6 [X] Запуск через bat-файл выборочных окон

[Джолли]

Так как я играю в 3-4 окна, то сделал себе удобный батник, который может запускать выборочные окна (если одно отвалилось и нужно запустить именно его).

Если вы хотите запустить все 6 окон - вводите 123456, если хотите только первые 3 - 123 вводите. Можно вводить 135, 12456 и тд.

Копируете код ниже в .bat файл, например startpw.bat (включите показ расширений, чтобы у вас был не startpw.bat.txt).

Я играю с каждым окном с отдельной копией клиента, так что у меня уникальные папки под каждого персонажа. Условно C:\Games\Comeback136.pw1\Element , C:\Games\Comeback136.pw2\Element и тд. Вы можете везде указать одинаковый путь. Не забудьте для каждого аккаунта подтвердить IP в ЛК.

Базовые настройки:

set "BASE=C:\Games" - путь к базовой папке с клиентами игры, все пути указываем БЕЗ \ в конце.
set "SUB1=Comeback136.pw1\Element" - пример первой папки, тоже без \ в конце
set "USER1=user1" - логин
set "PWD1=pass1" - пароль
set "ROLE1=Персонаж1" - имя перса, если хотите чтобы сразу в игру логинило, а не на окне чарселекта останавливался автовход
timeout /t 2 >nul - 2 секунды таймаута между запуском окон, чтобы не забанило за одновременный вход. Если все 6 окон запускаете разом - лучше увеличить это значение.

Собственно сама команда start /D "!BASE!\!SUB%N%!" ElementClient.exe startbypatcher game:cpw console:1 user:!USER%N%! pwd:!PWD%N%! role:!ROLE%N%! является немного модифицированной командой из примера в клиенте (та, что в /element/ElementClient_start.bat лежит), но только добавлен переход в нужную директорию (иначе будут ошибки, так как директория запуска скрипта и файл elementclient.exe могут лежать в разных дирах) и логин-пасс-чар передаются переменными.

Еще добавил возможность введя "c" закрыть все окна (если зависли, например), введенная строка "c123" закроет все окна и запустит 1,2 и 3 окно.

@echo off
chcp 65001 >nul
title Запуск клиентов PW

rem ================== НАСТРОЙКИ ==================
rem Базовая папка, где лежат все копии игры
set "BASE=C:\Games"

rem ---------- Персонаж 1 ----------
set "SUB1=Comeback136.pw1\Element\"
set "USER1=user1"
set "PWD1=pass1"
set "ROLE1=Персонаж1"

rem ---------- Персонаж 2 ----------
set "SUB2=Comeback136.pw2\Element\"
set "USER2=user2"
set "PWD2=pass2"
set "ROLE2=Персонаж2"

rem ---------- Персонаж 3 ----------
set "SUB3=Comeback136.pw3\Element\"
set "USER3=user3"
set "PWD3=pass3"
set "ROLE3=Персонаж3"

rem ---------- Персонаж 4 ----------
set "SUB4=Comeback136.pw4\Element\"
set "USER4=user4"
set "PWD4=pass4"
set "ROLE4=Персонаж4"

rem ---------- Персонаж 5 ----------
set "SUB5=Comeback136.pw5\Element\"
set "USER5=user5"
set "PWD5=pass5"
set "ROLE5=Персонаж5"

rem ---------- Персонаж 6 ----------
set "SUB6=Comeback136.pw6\Element\"
set "USER6=user6"
set "PWD6=pass6"
set "ROLE6=Персонаж6"
rem ================================================

:menu
cls
echo ============================================
echo   Кого запускаем?
echo ============================================
echo   1 - %ROLE1%
echo   2 - %ROLE2%
echo   3 - %ROLE3%
echo   4 - %ROLE4%
echo   5 - %ROLE5%
echo   6 - %ROLE6%
echo --------------------------------------------
echo   Введите номера подряд, например:
echo     1      - только первый
echo     12     - первый и второй
echo     135    - первый, третий и пятый
echo     123456 - все шесть
echo     c      - Закрыть все клиенты PW
echo     c123   - Закрыть всех и запустить 1, 2, 3
echo     0      - выход
echo ============================================
set "choice="
set /p "choice=Ваш выбор: "

if "%choice%"=="0" exit /b

set "KILL="
if /i "%choice:~0,1%"=="c" set "KILL=1"
if "%choice:~0,1%"=="с"  set "KILL=1"
if "%choice:~0,1%"=="С"  set "KILL=1"

if defined KILL taskkill /F /IM ElementClient.exe >nul 2>&1
if defined KILL echo Клиенты закрыты, запускаю выбранных...
if defined KILL set "choice=%choice:~1%"

if not "%choice:1=%"=="%choice%" call :run 1
if not "%choice:2=%"=="%choice%" call :run 2
if not "%choice:3=%"=="%choice%" call :run 3
if not "%choice:4=%"=="%choice%" call :run 4
if not "%choice:5=%"=="%choice%" call :run 5
if not "%choice:6=%"=="%choice%" call :run 6

exit /b

:run
setlocal enabledelayedexpansion
set "N=%~1"
set "DIR=!BASE!\!SUB%N%!"
start /D "!DIR!" ElementClient.exe startbypatcher game:cpw console:1 user:!USER%N%! pwd:!PWD%N%! role:!ROLE%N%!
timeout /t 2 >nul
endlocal
exit /b

Может кому-то будет полезно.